В разделе "Файлы" доступна для скачивания демо-версия программы. Демо-версия позволяет:

1. Протестировать программу на вашем устройстве ККТ
2. Протестировать драйвера 1С "Клиент-ККТ" на вашей конфигурации
3. Использовать программу в качестве эмулятора ККТ
4. Записывать в файл лога все обращения к драйверу ККТ (можно использовать для отладки и тестирования)

Ограничение демо-версии: не более 5 чеков после запуска службы (если перезапустить службу, то можно снова печатать 5 чеков)

В программу встроен эмулятор ККТ, который может работать в двух режимах:

1. В соответствии с «Требованиями к разработке драйверов подключаемого оборудования» версии 2.2
2. В соответствии с «Требованиями к разработке драйверов подключаемого оборудования» версии 3.1

Для использования эмулятора достаточно демо-версии программы

В программе есть возможность включить запись логов: вся информация о вызовах методов драйвера ККТ будет записываться в текстовой файл:

21.08.2019 10:47:25	Start on port 52111
Server mode: Native   InterfaceRevision: 2004   Dll: C:\Program Files\Modul\KKT\fptr10_1c_win32_10_4_2_0.dll

21.08.2019 10:50:02	ClientConnect 192.168.1.176

21.08.2019 10:50:02	Command Open
Параметр1=Неопределено

21.08.2019 10:50:03	Command completed

21.08.2019 10:50:03	Return
Параметр1="ATOL_KKT_1C83_V10#1"
Результат=Истина

21.08.2019 10:50:03	ClientDisconnect 192.168.1.176

21.08.2019 10:50:03	ClientConnect 192.168.1.176

21.08.2019 10:50:03	Command ProcessCheck
Параметр1="ATOL_KKT_1C83_V10#1"
Параметр2=Ложь
Параметр3="<?xml version="1.0" encoding="UTF-8"?>
<CheckPackage>
	<Parameters CashierName="Иванов Иван Иванович" PaymentType="1" SenderEmail="" CustomerPhone=""/>
	<Positions>
		<FiscalString Name="63155 Пакет-майка" Quantity="1" PriceWithDiscount="5" SumWithDiscount="5" Tax="none" SignCalculationObject="1"/>
		<Barcode BarcodeType="CODE39" Barcode="DA00-00032994210819"/>
	</Positions>
	<Payments Cash="5" ElectronicPayment="0" Credit="0" AdvancePayment="0" CashProvision="0"/>
</CheckPackage>"
Параметр4=0
Параметр5=0
Параметр6=""
Параметр7=""

21.08.2019 10:50:07	Command completed
Mode=work
21.08.2019 10:50:07	Return
Параметр1 без изменений
Параметр2 без изменений
Параметр3 без изменений
Параметр4=7435
Параметр5=97
Параметр6="4149700262"
Параметр7="www.nalog.ru"
Результат=Истина

21.08.2019 10:50:07	ClientDisconnect 192.168.1.176

21.08.2019 10:50:07	ClientConnect 192.168.1.176

21.08.2019 10:50:07	Command Close
Параметр1="ATOL_KKT_1C83_V10#1"

21.08.2019 10:50:07	Command completed

21.08.2019 10:50:07	Return
Параметр1 без изменений
Результат=Истина

21.08.2019 10:50:07	ClientDisconnect 192.168.1.176

Информация в файле лога ориентирована на программистов. В ней содержится:

• Имя вызываемого метода компоненты
• Входные параметры
• Выходные параметры (т.е. параметры после вызова метода)
• Признак успешности выполнения
• Возвращаемый результат

Для сбора логов с целью тестирования конфигурации достаточно демо-версии программы

1. Интернет-сайт должен интегрироваться с 1С через web-сервисы или http-сервисы.
2. На сайте принимается заказ покупателя. Этот заказ переносится в 1С (через web- или http-сервис)
3. На сайте принимается оплата от покупателя с помощью Интернет-эквайринга. В 1С создается документ "Оплата от покупателя платёжной картой" (через web- или http-сервис)
4. В 1С вызывается функция для пробития чека (через web- или http-сервис). Эта функция возвращает параметры пробитого чека (№ фн, фискальный признак, № фискального документа и др.).
5. ОФД отправляет электронный чек покупателю (по e-mail или SMS). Условия отправки электронного чека нужно уточнить у вашего ОФД.

Рассмотрим подробнее функцию пробития чека. Функция вызывается в контексте сервера. Поэтому типовой механизм работы с торговым оборудованием будет недоступен. Используем следующий код:

//Параметры 
//Ссылка - документ "Оплата от покупателя платежной картой"
Функция ПечатьЧека(Ссылка) Экспорт
	//Драйвер KKT_Client_3001 нужно поместить в общий макет
	Если ПодключитьВнешнююКомпоненту("ОбщийМакет.KKT_Client_3001","ZY312",ТипВнешнейКомпоненты.Native)<>Истина Тогда
		//что-то пошло не так...
		Возврат Неопределено;
	КонецЕсли;
	
	Компонента = Новый("AddIn.ZY312.MKClient_3001");
	Компонента.УстановитьПараметр("Server","192.168.0.61"); //адрес компьютера, к которому подключена ККТ
	Компонента.УстановитьПараметр("Port",52111);
	
	ИДУстройства = "";
	Если Компонента.Подключить(ИДУстройства)<>Истина Тогда
		//что-то пошло не так...
		Возврат Неопределено;
	КонецЕсли;
	
	Электронно = Истина;
	ВыходныеПараметры = "";
	ДанныеЧека = "...."; /// здесь нужно сформировать XML пакет, использую параметр "Ссылка" и функции типовой конфигурации
	Если Компонента.СформироватьЧек(ИДУстройства,Электронно,ДанныеЧека,ВыходныеПараметры)=Истина Тогда  //Подразумеваются требования к разработке драйверов подключаемого оборудования версии 3.1
		Результат = Новый Структура;
		//здесь нужно разобрать XML пакет ВыходныеПараметры и заполнить результат
	Иначе
		Результат = Неопределено;
	КонецЕсли;
	
	Компонента.Отключить(ИДУстройства);
	
	Возврат Результат;
КонецФункции

1. Установка

Запустить файл KKT_Setup.exe:

После установки в указанном каталоге появятся файлы:

• KKT_Server.exe - служба «Сервер ККТ»
• KKT_Server_Setting.exe - программа для настройки параметров
• 1С\KKT_Client_хххх.zip - драйвер для 1С по технологии Native API
• 1С\KKT_Client_хххх_Android.zip - драйвер для мобильного приложения 1С
• 1С\KKT_Client_хххх_77.zip - драйвер для старых версий платформ (7.7, 8.0, 8.1, 8.2) по технологии COM
• 1С\МодульКлиентККТ_хххх.epf - обработка обслуживания ККТ для конфигураций УТ10.х, КА1.х и т.п.
• 1С\MKClient_хххх.efd и MKClient_хххх.ert - обработка обслуживания ККТ для конфигурации 1С:7.7 Торговля и склад 9.2

Число в имени файла обозначает:

• 2002 - соответствие требованиям к разработке драйверов подключаемого оборудования версии 2.2 - 2.5
• 3001 - соответствие требованиям к разработке драйверов подключаемого оборудования версии 3.0 - 3.1

Необходимо удостовериться, что служба установлена: Пуск – Панель управления – Администрирование – Службы:

Перед запуском службы нужно настроить параметры (см. ниже). При необходимости, службу можно установить/удалить вручную:
KKT_Server.exe –i (для установки)
KKT_Server.exe –u (для удаления)

2. Настройка параметров

Запустить файл KKT_Server_Setting.exe:

• В поле «Порт» указать номер порта TCP, который будет использован «Сервером ККТ».
• «Записывать log» – подробная информация о работе программы будет сохраняться в файл log.txt.
• В поле «Драйвер КТТ» указать путь к драйверу 1С из комплекта поставки онлайн-кассы.
• В поле «Имя класса» указать имя компоненты (выбирается по кнопке «...»).
• При необходимости поставить галку «Режим эмуляции». В этом режиме данные не будут отправляться в онлайн-кассу, но будут сохраняться в log. Режим предназначен для тестирования.
• «Не отключать устройство» – при этой настройке «Сервер ККТ» будет держать ККТ в состоянии «Подключено» (поступающие от клиентов команды «отключить» будут игнорироваться). Эта настройка позволяет исключить коллизию, когда отключение ККТ с одного рабочего места отключат это ККТ для других рабочих мест.

Настроить параметры подключения можно по кнопке «Параметры»

Проверить связь с онлайн-кассой можно по кнопке «Тест устройства»

3. Настройка 1С (на примере «1С:Розница 2.2»)

Установка драйвера ККТ-клиент:

Меню Администрирование–Подключаемое оборудование–Драйверы оборудования–Добавить новый драйвер из файла, указать файл KKT_Client_2002.zip или KKT_Client_3001.zip

Важно правильно выбрать драйвер "ККТ-клиент", чтобы он был совместим с драйвером производителя ККТ. Как выбрать драйвер?

При тестировании устройства в программе KKT_Server_Setting.exe выдается подсказка: "Ревизия интерфейса драйвера NNNN".

• если ревизия интерфейса от 2002 до 2005, значит в 1С нужно использовать KKT_Client_2002
• если ревизия интерфейса от 3000 и выше, значит в 1С нужно использовать KKT_Client_3001

Далее нажать кнопки «Записать» и «Функции–Установить драйвер»:

Установка ККТ:

Меню Администрирование–Подключаемое оборудование, указать «Тип оборудования»: ККТ с передачей данных, далее нажать кнопку «Создать». Выбрать драйвер оборудования «Модуль:ККТ-клиент»:

Нажать кнопку «Настроить...» и указать параметры «Сервер» и «Порт» - компьютер и номер порта, на котором работает «Сервер ККТ». Для проверки связи нужно нажать кнопку «Тест подключения»:

Понятие «Сервер» в параметрах подключения обозначает компьютер, непосредственно к которому подключен кассовый аппарат.

• Если вы настраиваете 1С на том же самом компьютере, то в параметре "Сервер" можно указать "127.0.0.1"
• Если вы настраиваете 1С на другом компьютере, то в параметре "Сервер" нужно указать имя (или ip-адрес) того компьютера, к которому подключен кассовый аппарат

Если вы используете нашу программу подключения к онлайн-кассе, то во всех программах 1С, которые будут работать с этой кассой, подключение должно настраиваться через драйвер "ККТ-клиент".

Не получиться использовать на одном компьютере драйвер производителя, а на другом – драйвер "ККТ-клиент", т.к. один из драйверов "захватит" устройство, а второй драйвер получит ошибку "Порт занят".

4. Настройка WEB-клиента (на примере «Google Chrome» и «1С:Розница 2.2»)

1. Нужно установить Расширение для работы с 1С:Предприятием. Чтобы проверить, установлено ли расширение, нужно набрать в адресной строке браузера chrome://extensions/

2. В режиме "толстого" или "тонкого" клиента в базу должен быть загружен драйвер KKT_Client.zip (см. "Установка драйвера ККТ")

3. Далее в режиме WEB-клиента: меню Администрирование–Подключаемое оборудование, указать «Тип оборудования»: ККТ с передачей данных, далее нажать кнопку «Создать». Выбрать драйвер оборудования «Модуль:ККТ-клиент»:

Нажать кнопку "Записать и закрыть"

4. В форме списка подключаемого оборудования нажать кнопки "Настроить", "Установить драйвер" и "Продолжить":

Будет загружен файл "1CExtensionXXX.exe". Нажать "Открыть":

Запуститься установщик внешней компоненты "ККТ-клиент для Chrome и Firefox". После завершения установки должно появиться сообщение "Установка драйвера завершена":

5. Далее нужно указать параметры подключения "Сервер" и "Порт" и нажать кнопку "Тест подключения":

Примечания:

Внешняя компонента "ККТ-клиент для Chrome и Firefox" устанавливается в каталог "Program files" для всех пользователей системы. Для установки может потребоваться запуск браузера с правами администратора.

Перед установкой новой версии компоненты необходимо удалить старую версию через "Панель управления" - "Программы и компоненты":

5. Регистрация программы

Сразу после установки программа работает в демо-режиме: не более 5 чеков после запуска службы. Регистрация программы привязывает полученный пин-код к ИНН организации, от имени которой будут пробиваться чеки. 

Для регистрации нужно запустить программу KKT_Server_Setting.exe и нажать кнопку "Еще - Регистрация":

Далее нужно указать пин-код, полученный при покупке программы и ИНН организации, от имени которой будут пробиваться чеки. 

При нажатии кнопки "ОК" программа проверит пин-код на сервере регистрации (для этого должен быть доступен выход в Интернет) и создаст файл типа хххххх.inn, где хххххх - указанный ИНН. Этот файл должен находиться в той же папке, где находится файл KKT_Server.exe.

Одну программу можно регистрировать несколько раз для разных ИНН. Для этого потребуются приобрести нужное количество пин-кодов.

В случае потери файла хххххх.inn (например, при переустановке ОС), можно повторно зарегистрировать программу, указав пин-код и соответствующий ИНН.

Проверить режим работы программы (демо или полный) можно по кнопке "Еще - Режим".

Далее нужно перезапустить службу "Сервер ККТ".

1. В справочнике "Кассы ККМ" указывается рабочее место. То есть ККМ привязывается только к одному рабочему месту.
    
2. В документе "Кассовая смена" указывается экземпляр подключаемого устройства (реквизит "Фискальное­Устройство"). То есть нельзя получить информацию о кассовой смене на другом рабочем месте, т.к. на другом рабочем месте используется другой экземпляр подключаемого устройства.
    

Необходимые изменения:

1. В справочник "Рабочие места" добавить реквизит "Касса ККМ". Это позволить использовать одну ККМ на нескольких рабочих местах.
2. В модуле объекта документа "Кассовая смена" в событии "ПередЗаписью" очищать значение реквизита "ФискальноеУстройство".

   Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)
   	Если ОбменДанными.Загрузка=Ложь Тогда
   		ФискальноеУстройство = Неопределено;
   	КонецЕсли;
   КонецПроцедуры

3. Изменить процедуру "Менеджер­Оборудования­Клиент.­Начать­Выполнение­Команды­_Выбрать­Устройство­Завершение" таким образом, чтобы получать статус последней смены не по "ФискальномуУстройству" а по "КассеККМ".

   //вместо
   //СтатусПоследнейСмены = МенеджерОборудованияВызовСервера.ПолучитьСтатусПоследнейСмены(ИдентификаторУстройства);
   //написать:
   
   лКассаККМ = Неопределено;
   Если ТипЗнч(Параметры)=Тип("Структура") Тогда
   	Если Параметры.Свойство("ВходныеПараметры") И Параметры.ВходныеПараметры.Свойство("КассаККМ") Тогда
   		лКассаККМ = Параметры.ВходныеПараметры.КассаККМ;
   
   	ИначеЕсли Параметры.Свойство("ОповещениеПриЗавершении") И ТипЗнч(Параметры.ОповещениеПриЗавершении.ДополнительныеПараметры)=Тип("Структура") И Параметры.ОповещениеПриЗавершении.ДополнительныеПараметры.Свойство("КассаККМ") Тогда
   		лКассаККМ = Параметры.ОповещениеПриЗавершении.ДополнительныеПараметры.КассаККМ;
   	КонецЕсли;
   КонецЕсли;
   
   Если Не ЗначениеЗаполнено(лКассаККМ) Тогда
   	лКассаККМ = СерверККТ_ВызовСервера.ПолучитьКассуККМ(МенеджерОборудованияКлиентПовтИсп.ПолучитьРабочееМестоКлиента());
   КонецЕсли;
   
   СтатусПоследнейСмены = СерверККТ_ВызовСервера.ПолучитьСтатусПоследнейСмены(лКассаККМ);

   Общий модуль СерверККТ_ВызовСервера:

   Функция ОписаниеПоследнейКассовойСмены(КассаККМ)
   	Запрос = Новый Запрос();
   	Запрос.Текст =
   	"ВЫБРАТЬ РАЗРЕШЕННЫЕ ПЕРВЫЕ 1
   	|	КассоваяСмена.Ссылка КАК КассоваяСмена,
   	|    КассоваяСмена.ФискальноеУстройство КАК ФискальноеУстройство,
   	|    КассоваяСмена.НачалоКассовойСмены КАК НачалоКассовойСмены,
   	|    КассоваяСмена.ОкончаниеКассовойСмены КАК ОкончаниеКассовойСмены,
   	|	ДОБАВИТЬКДАТЕ(КассоваяСмена.НачалоКассовойСмены, ДЕНЬ, 1) КАК ДатаИстеченияСрокаДействия,
   	|    КассоваяСмена.Организация КАК Организация,
   	|    КассоваяСмена.Статус КАК Статус
   	|ИЗ
   	|	Документ.КассоваяСмена КАК КассоваяСмена
   	|ГДЕ
   	|	КассоваяСмена.КассаККМ = &КассаККМ
   	|	И КассоваяСмена.Проведен
   	|
   	|УПОРЯДОЧИТЬ ПО
   	|    КассоваяСмена.НачалоКассовойСмены УБЫВ,
   	|    КассоваяСмена.НомерСменыККТ УБЫВ";
   	Запрос.УстановитьПараметр("КассаККМ", КассаККМ);
   	Результат = Запрос.Выполнить().Выгрузить();
   
   	Если Результат.Количество() = 0 Тогда
   		Возврат Неопределено;
   	Иначе
   		СтруктураРезультат = Новый Структура();
   		Для Каждого КолонкаРезультата Из Результат.Колонки Цикл
   			СтруктураРезультат.Вставить(КолонкаРезультата.Имя, Результат[0][КолонкаРезультата.Имя]);
   		КонецЦикла;
   		Возврат СтруктураРезультат;
   	КонецЕсли;
   
   КонецФункции
   
   Функция ПолучитьСтатусПоследнейСмены(КассаККМ) Экспорт
   
   	УстановитьПривилегированныйРежим(Истина);
   
   	РезультатОперации = Новый Структура();
   	РезультатОперации.Вставить("Активна", Ложь);
   	РезультатОперации.Вставить("Открыта", Ложь);
   	РезультатОперации.Вставить("ТекущийНомерЧека");
   	РезультатОперации.Вставить("НомерСмены");
   	РезультатОперации.Вставить("КассоваяСмена");
   	РезультатОперации.Вставить("НомерСменыККТ");
   	РезультатОперации.Вставить("ДатаИстеченияСрокаДействия");
   
   	ОписаниеПоследнейСмены = ОписаниеПоследнейКассовойСмены(КассаККМ);
   
   	Если Не (ОписаниеПоследнейСмены = Неопределено) Тогда
   		РезультатОперации.Открыта = ОписаниеПоследнейСмены.Статус = Перечисления.СтатусыКассовойСмены.Открыта;
   		РезультатОперации.Активна = РезультатОперации.Открыта
   			И ОписаниеПоследнейСмены.ДатаИстеченияСрокаДействия > МенеджерОборудованияВызовСервера.ДатаСеанса();
   		РезультатОперации.КассоваяСмена    = ОписаниеПоследнейСмены.КассоваяСмена;
   		РезультатОперации.НомерСмены       = ОписаниеПоследнейСмены.КассоваяСмена.Номер;
   		РезультатОперации.НомерСменыККТ    = ОписаниеПоследнейСмены.КассоваяСмена.НомерСменыККТ;
   		РезультатОперации.ДатаИстеченияСрокаДействия = ОписаниеПоследнейСмены.ДатаИстеченияСрокаДействия;
   	КонецЕсли;
   
   	Возврат РезультатОперации;
   
   	УстановитьПривилегированныйРежим(Ложь);
   КонецФункции
   
   Функция ПолучитьКассуККМ(РабочееМесто) Экспорт
   	УстановитьПривилегированныйРежим(Истина);
   	Запрос = Новый Запрос(
   	"ВЫБРАТЬ
   	|	Спр.СерверККТ_КассаККМ КАК КассаККМ
   	|ИЗ
   	|	Справочник.РабочиеМеста КАК Спр
   	|ГДЕ
   	|	Спр.Ссылка = &Ссылка");
   	Табл = Запрос.Выполнить().Выгрузить();
   	УстановитьПривилегированныйРежим(Ложь);
   
   	Если Табл.Количество()=0 Тогда
   		Возврат Справочники.КассыККМ.ПустаяСсылка();
   	Иначе
   		Возврат Табл[0].КассаККМ;
   	КонецЕсли;
   КонецФункции

4. В форме "Обработки.­РМКУправляемыйРежим.­ФормаМеню" изменить процедуру Проверить­Общую­Возможность­Работы таким образом, чтобы касса ККМ бралась из справочника "Рабочие места".

   //Изменить запрос на:
   
   Запрос = Новый Запрос;
   Запрос.Текст =
   "ВЫБРАТЬ РАЗРЕШЕННЫЕ
   |	КассыККМ.Ссылка КАК КассаККМ,
   |	КассыККМ.Магазин,
   |	КассыККМ.Владелец КАК Организация,
   |	ВЫБОР
   |		КОГДА КассыККМ.ПодключаемоеОборудование.ТипОборудования = &ККТОнлайн
   |			ТОГДА ИСТИНА
   |		ИНАЧЕ ЛОЖЬ
   |	КОНЕЦ КАК НеобходимостьПроверятьФизЛицо
   |ИЗ
   |	Справочник.КассыККМ КАК КассыККМ
   |ГДЕ Ссылка=&Ссылка";
   
   Запрос.УстановитьПараметр("Ссылка", РабочееМесто.СерверККТ_КассаККМ);
   Запрос.УстановитьПараметр("ККТОнлайн", Перечисления.ТипыПодключаемогоОборудования.ККТ);
   
   Результат = Запрос.Выполнить();

Скачать расширение с этими изменениями можно в разделе "Файлы"

Ограничения типовой конфигурации "1С:Управление Торговлей 10.3":
В документе "Кассовая смена" указывается экземпляр подключаемого устройства (реквизит "Фискальное­Устройство"). То есть нельзя получить информацию о кассовой смене на другом рабочем месте, т.к. на другом рабочем месте используется другой экземпляр подключаемого устройства.

Необходимые изменения:

1. В модуле объекта документа "Кассовая смена" в событии "Перед­Записью" очищать значение реквизита "Фискальное­Устройство".

   Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)
   	Если ОбменДанными.Загрузка=Ложь Тогда
   		ФискальноеУстройство = Неопределено;
   	КонецЕсли;
   КонецПроцедуры

2. Изменить процедуру "ОбщийМодуль.­Кассовые­Смены­Вызов­Сервера.­Описание­Последней­Кассовой­Смены" таким образом, чтобы получать статус последней смены не по "Фискальному­Устройству" а по "КассеККМ".

   //Изменить запроc на:
   Запрос.Текст =
   "ВЫБРАТЬ РАЗРЕШЕННЫЕ ПЕРВЫЕ 1
   |	КассоваяСмена.Ссылка КАК КассоваяСмена,
   |	КассоваяСмена.ФискальноеУстройство,
   |	КассоваяСмена.НачалоКассовойСмены,
   |	КассоваяСмена.ОкончаниеКассовойСмены,
   |	ДОБАВИТЬКДАТЕ(КассоваяСмена.НачалоКассовойСмены, ДЕНЬ, 1) КАК ДатаИстеченияСрокаДействия,
   |	КассоваяСмена.Организация,
   |	КассоваяСмена.Статус,
   |	КассоваяСмена.ДатаСменыККТ,
   |	КассоваяСмена.НомерСменыККТ,
   |	КассоваяСмена.КассаККМ
   |ИЗ
   |	Документ.КассоваяСмена КАК КассоваяСмена
   |		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ТорговоеОборудование КАК Рег
   |		ПО КассоваяСмена.КассаККМ = Рег.КассаККМ
   |			И (Рег.Идентификатор = &ФискальноеУстройство)
   |			И (КассоваяСмена.Проведен)
   |
   |УПОРЯДОЧИТЬ ПО
   |	КассоваяСмена.НачалоКассовойСмены УБЫВ";

3. Изменить процедуру "Документ.­Кассовые­Смены.­Форма­Списка.­Закрыть­Кассовую­Смену" таким образом, чтобы получать ККТ не из документа, а из списка подключенных устройств.

   &НаКлиенте
   Процедура ЗакрытьКассовуюСмену(Команда)
   
   	Если Не КассовыеСменыВызовСервера.ЕстьПравоНаЗакрытиеСмены() Тогда
   		Предупреждение("Нарушение прав доступа");
   		Возврат;
   	КонецЕсли;
   
   	ОчиститьСообщения();
   
   	ТекущиеДанныеСписка = Элементы.Список.ТекущиеДанные;
   	Если ТекущиеДанныеСписка <> Неопределено Тогда
   		СтатусСмены = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(ТекущиеДанныеСписка.Ссылка, "Статус");
   		Если СтатусСмены = ПредопределенноеЗначение("Перечисление.СтатусыКассовойСмены.Закрыта") Тогда
   			ОбщегоНазначения.СообщитьОбОшибке("Смена уже закрыта.");
   			Возврат;
   		КонецЕсли;
   	Иначе
   		ОбщегоНазначения.СообщитьИнформациюПользователю("Выберите смену, которую нужно закрыть.");
   		Возврат;
   	КонецЕсли;
   
   	КассаККМ = ТекущиеДанныеСписка.КассаККМ;
   	Если Не ЗначениеЗаполнено(КассаККМ) Тогда
   		Возврат;
   	КонецЕсли;
   	МассивФУ = ПолучитьСерверТО().ПолучитьСписокУстройств(Перечисления.ВидыТорговогоОборудования.ККТ, КассаККМ);
   
   	КоличествоФУ = МассивФУ.Количество();
   	Если КоличествоФУ = 0 Тогда
   		Возврат;
   	ИначеЕсли КоличествоФУ = 1 Тогда
   		ККТ = МассивФУ[0];
   	Иначе
   		СписокФУ = РаботаСТорговымОборудованием.ПолучитьСписокУстройствТОДляВыбора(МассивФУ);
   
   		х = СписокФУ.ВыбратьЭлемент("Необходимо выбрать фискальное устройство");
   		Если х=Неопределено Тогда
   			Возврат;
   		Иначе
   			ККТ = х.Значение;
   		КонецЕсли;
   	КонецЕсли;
   
   	КассовыеСменыКлиент.ЗакрытьКассовуюСмену(ККТ, ТекущиеДанныеСписка.Ссылка);
   
   	Элементы.Список.Обновить();
   
   КонецПроцедуры

В справочник «Настройки РМК» добавлена возможность выбора устройства на других рабочих местах:

Пример настройки нескольких рабочих мест на работу с одним ККТ:

1.   ККТ нужно подключить к программе "Сервер ККТ"
2.   В 1С на первом рабочем месте:
   1. В справочник "Драйверы оборудования" добавить драйвер "Клиент ККТ"
   2. В справочник "Подключаемое оборудование" добавить оборудование "ККТ" с драйвером "Клиент ККТ"
   3. В справочнике "Настройки РМК" указать добавленное оборудование
3. В 1С на втором (и последующих) рабочем месте в справочнике "Настройки РМК" в поле ввода "Все устройства" указать оборудование, добавленное в п 2.b.

1. Служба "Сервер ККТ" подключается к кассовому аппарату используя драйвера от производителя ККТ (например, драйвера выполненные по технологии Native API для 1С:8.3).
2. Далее служба "Сервер ККТ" открывает TCP-порт прослушивания входящий соединений.
3. Программа 1С:7.7 подключается к этому порту используя драйвер "Клиент-ККТ" (драйвер входит в дистрибутив "Сервера ККТ").
4. Далее 1С:7.7 и "Сервер ККТ" обмениваются данными по своему внутреннему протоколу. При этом для 1С скрыто, какой кассовый аппарат и какой драйвер используется.

Перем Объект;
Перем Параметр_Сервер;
Перем Параметр_Порт;


Процедура ПриОткрытии()
	
	Если ЗагрузитьВнешнююКомпоненту("v7plus.dll")<>1 Тогда
		Форма.Параметр.Установить("Результат", 0);
		Форма.Параметр.Установить("ОписаниеРезультата", "Компонента v7plus.dll не найдена!");
		СтатусВозврата(0);
		Возврат;
	КонецЕсли; 
	
	Компонента = "KKT_Client_3001_77.dll";
	Если ЗагрузитьВнешнююКомпоненту(Компонента)=0  Тогда
		Сообщить("Не удалось загрузить внешнюю компоненту """ + Компонента + """");
		СтатусВозврата(0);
		Возврат;
	Иначе
		Попытка
			Объект = СоздатьОбъект("AddIn.MKClient_3001_77");
		Исключение
		КонецПопытки;
		
		Если ПустоеЗначение(Объект)=1 Тогда
			Сообщить("Не удалось создать объект внешней компоненты");
			СтатусВозврата(0);
			Возврат;
		КонецЕсли;
	КонецЕсли;

	Параметр_Сервер = "192.168.0.61";
	Параметр_Порт = 52111;
КонецПроцедуры

Процедура Атрибут(хмлКорень,хмлЭлемент, ИмяАтрибута, ЗначениеАтрибута)   
	хмлАтрибут = хмлКорень.СоздатьУзел("attribute", ИмяАтрибута);
	хмлАтрибут.Значение = ЗначениеАтрибута;
	хмлЭлемент.ДобавитьПодчиненный(хмлАтрибут);	
КонецПроцедуры 


Функция Подключиться(Отказ,ОписаниеРезультата)
	
	Если ПустоеЗначение(Объект)=1 Тогда
		ОписаниеРезультата = "Объект внешней компоненты не создан";
		Отказ = 1;
		Возврат "";
	КонецЕсли;

	ф = Объект.УстановитьПараметр("Server", Параметр_Сервер);
	Если ПустоеЗначение(ф)=1 Тогда
		Объект.GetLastError(ОписаниеРезультата);
		Отказ = 1;
		Возврат "";
	КонецЕсли;

	ф = Объект.УстановитьПараметр("Port", Параметр_Порт);
	Если ПустоеЗначение(ф)=1 Тогда
		Объект.GetLastError(ОписаниеРезультата);
		Отказ = 1;
		Возврат "";
	КонецЕсли;
	
	ИДУстройства = "";
	ф = Объект.Подключить(ИДУстройства);
	Если ПустоеЗначение(ф)=1 Тогда
		Объект.GetLastError(ОписаниеРезультата);
		Отказ = 1;
		Возврат "";
	КонецЕсли;

	Возврат ИДУстройства;
КонецФункции


Процедура ОткрытьСмену(ИДУстройства, Кассир, ИНН_Кассира, НомерСмены, Отказ, ОписаниеРезультата)
	
	XMLАнализатор = СоздатьОбъект("AddIn.XMLParser");
	
	// Создаем XML-файл
	XML	= XMLАнализатор.СоздатьДокумент();
	XML.Кодировка = "UTF-8";
	InputParameters	= XML.СоздатьПодчиненныйЭлемент("InputParameters");
	Parameters	= InputParameters.СоздатьПодчиненныйЭлемент("Parameters");
	Атрибут(XML, Parameters, "CashierName", Кассир);
	Атрибут(XML, Parameters, "CashierVATIN", ИНН_Кассира); 
	
	XML.Записать(КаталогПользователя() + "Modul_OpenShift.xml");
	
	// Читаем XML-файл в кодировке UTF-8 
	Поток = CreateObject("Adodb.Stream");
	Поток.Charset = "utf-8";
	Поток.Type = 2;
	Поток.Mode= 3;
	Поток.Open();
	Поток.LoadFromFile(КаталогПользователя() + "Modul_OpenShift.xml");
	ВходныеПараметры = Поток.ReadText();
	Поток.Close();
	
	НомерДокумента = "";
	ВыходныеПараметры = "";
	ф = Объект.ОткрытьСмену(ИДУстройства, ВходныеПараметры, ВыходныеПараметры);
	Если ПустоеЗначение(ф)=1 Тогда
		Объект.GetLastError(ОписаниеРезультата);
		Отказ = 1;
		Возврат;
	КонецЕсли;

КонецПроцедуры   


Процедура ЗакрытьСмену(ИДУстройства, Кассир, ИНН_Кассира, НомерСмены, Отказ, ОписаниеРезультата)
	
	XMLАнализатор	= СоздатьОбъект("AddIn.XMLParser");
	
	XML	= XMLАнализатор.СоздатьДокумент();
	XML.Кодировка = "UTF-8";
	InputParameters	= XML.СоздатьПодчиненныйЭлемент("InputParameters");
	Parameters	= InputParameters.СоздатьПодчиненныйЭлемент("Parameters");
	Атрибут(XML, Parameters, "CashierName", Кассир);
	Атрибут(XML, Parameters, "CashierVATIN", ИНН_Кассира); 
	
	XML.Записать(КаталогПользователя() + "Modul_CloseShift.xml");
	
	Поток = CreateObject("Adodb.Stream");
	Поток.Charset = "utf-8";
	Поток.Type = 2;
	Поток.Mode= 3;
	Поток.Open();

	Поток.LoadFromFile(КаталогПользователя() + "Modul_CloseShift.xml");
	ВходныеПараметры = Поток.ReadText();
	Поток.Close();
	
	
	НомерДокумента = "";
	ВыходныеПараметры = "";
	ф = Объект.ЗакрытьСмену(ИДУстройства, ВходныеПараметры, ВыходныеПараметры);
	Если ПустоеЗначение(ф)=1 Тогда
		Объект.GetLastError(ОписаниеРезультата);
		Отказ = 1;
		Возврат;
	КонецЕсли;

КонецПроцедуры


Функция ПечататьЧек(ИДУстройства, Кассир, СписокТоваров, СуммаНал, СуммаБезнал, Отказ, ОписаниеРезультата)
	
	XMLАнализатор	= СоздатьОбъект("AddIn.XMLParser");
	
	XML = XMLАнализатор.СоздатьДокумент();
	XML.Кодировка = "UTF-8";
	CheckPackage = XML.СоздатьПодчиненныйЭлемент("CheckPackage");
	Parameters = CheckPackage.СоздатьПодчиненныйЭлемент("Parameters");
	Атрибут(XML, Parameters, "OperationType", 1);  //Приход денежных средств
	Атрибут(XML, Parameters, "TaxationSystem", 3); //ЕНВД
	Атрибут(XML, Parameters, "CashierName", Кассир); 

	Positions = CheckPackage.СоздатьПодчиненныйЭлемент("Positions");
	
	СписокТоваров.ВыбратьСтроки();
	Пока СписокТоваров.ПолучитьСтроку()=1 Цикл
		FiscalString = Positions.СоздатьПодчиненныйЭлемент("FiscalString");
		Атрибут(XML, FiscalString, "Name", СписокТоваров.Наименование);
		Атрибут(XML, FiscalString, "Quantity", СписокТоваров.Количество);
		Атрибут(XML, FiscalString, "PriceWithDiscount", СписокТоваров.Цена); 
		Атрибут(XML, FiscalString, "AmountWithDiscount", СписокТоваров.Сумма);
		Атрибут(XML, FiscalString, "VATRate", СписокТоваров.СтавкаНДС); 
	КонецЦикла;	
	
	Payments = CheckPackage.СоздатьПодчиненныйЭлемент("Payments");
	Атрибут(XML, Payments, "Cash", СуммаНал); 
	Атрибут(XML, Payments, "ElectronicPayment", СуммаБезнал);
    
	XML.Записать(КаталогПользователя() + "Modul_ProcessCheck.xml");
	
	Поток = CreateObject("Adodb.Stream");
	Поток.Charset = "utf-8";
	Поток.Type = 2;
	Поток.Mode= 3;
	Поток.Open();
	
	Поток.LoadFromFile(КаталогПользователя() + "Modul_ProcessCheck.xml");
	ВходныеПараметры = Поток.ReadText();
	Поток.Close();
	
	ВыходныеПараметры = ""; 
	ф = Объект.СформироватьЧек(ИДУстройства, 0, ВходныеПараметры, ВыходныеПараметры);
	Если ПустоеЗначение(ф)=1 Тогда
		Объект.GetLastError(ОписаниеРезультата);
		Отказ = 1;
	КонецЕсли;
		
КонецФункции


Процедура Отключиться(ИДУстройства,Отказ,ОписаниеРезультата)

	ф = Объект.Отключить(ИДУстройства);
	Если ПустоеЗначение(ф)=1 Тогда
		Объект.GetLastError(ОписаниеРезультата);
		Отказ = 1;
		Возврат;
	КонецЕсли;

КонецПроцедуры


Процедура КнопкаОткрытьСмену()
	Отказ = 0;
	ОписаниеРезультата = "";
	ИДУстройства = Подключиться(Отказ,ОписаниеРезультата);
	Если Отказ=1 Тогда
		Сообщить(ОписаниеРезультата);
		Возврат;
	КонецЕсли;
	
	ОткрытьСмену(ИДУстройства,"ФИО кассира","ИНН кассира",1,Отказ,ОписаниеРезультата);
	Если Отказ=1 Тогда
		Сообщить(ОписаниеРезультата);
	КонецЕсли;
	
	Отказ = 0;
	Отключиться(ИДУстройства,Отказ,ОписаниеРезультата);
	Если Отказ=1 Тогда
		Сообщить(ОписаниеРезультата);
		Возврат;
	КонецЕсли;

КонецПроцедуры

Процедура КнопкаЧек()
	Отказ = 0;
	ОписаниеРезультата = "";
	ИДУстройства = Подключиться(Отказ,ОписаниеРезультата);
	Если Отказ=1 Тогда
		Сообщить(ОписаниеРезультата);
		Возврат;
	КонецЕсли;
	
	//Пример табличной части
	СписокТоваров = СоздатьОбъект("ТаблицаЗначений");
	СписокТоваров.НоваяКолонка("Наименование","Строка");
	СписокТоваров.НоваяКолонка("Количество","Число",10,3);
	СписокТоваров.НоваяКолонка("Цена","Число",15,2);
	СписокТоваров.НоваяКолонка("Сумма","Число",15,2);
	СписокТоваров.НоваяКолонка("СтавкаНДС","Строка");
	
	СписокТоваров.НоваяСтрока();
	СписокТоваров.Наименование = "Булка сдобная";
	СписокТоваров.Количество = 2;
	СписокТоваров.Цена = 15;
	СписокТоваров.Сумма = СписокТоваров.Количество*СписокТоваров.Цена;
	СписокТоваров.СтавкаНДС = "none"; //Без НДС

	
	ПечататьЧек(ИДУстройства,"ФИО кассира",СписокТоваров,СписокТоваров.Итог("Сумма"),0,Отказ,ОписаниеРезультата);
	Если Отказ=1 Тогда
		Сообщить(ОписаниеРезультата);
	КонецЕсли;
	
	Отказ = 0;
	Отключиться(ИДУстройства,Отказ,ОписаниеРезультата);
	Если Отказ=1 Тогда
		Сообщить(ОписаниеРезультата);
		Возврат;
	КонецЕсли;

КонецПроцедуры


Процедура КнопкаЗакрытьСмену()
	Отказ = 0;
	ОписаниеРезультата = "";
	ИДУстройства = Подключиться(Отказ,ОписаниеРезультата);
	Если Отказ=1 Тогда
		Сообщить(ОписаниеРезультата);
		Возврат;
	КонецЕсли;
	
	ЗакрытьСмену(ИДУстройства,"ФИО кассира","ИНН кассира",1,Отказ,ОписаниеРезультата);
	Если Отказ=1 Тогда
		Сообщить(ОписаниеРезультата);
	КонецЕсли;
	
	Отказ = 0;
	Отключиться(ИДУстройства,Отказ,ОписаниеРезультата);
	Если Отказ=1 Тогда
		Сообщить(ОписаниеРезультата);
		Возврат;
	КонецЕсли;

КонецПроцедуры

Скачать пример использования компоненты "ККТ-клиент" на 1С:7.7 можно в разделе "Файлы"

Если у вас возникли проблемы с запуском службы "Сервер ККТ" или с тестом драйвера "Клиент ККТ", то мы предлагаем воспользоваться небольшой утилитой TCP_test.exe, которую можно скачать в разделе "Файлы".

Утилита TCP_test.exe предназначена для тестирования TCP-соединений. Может использоваться для тестирования не только "Сервера ККТ", но и любых других программ.

Методика тестирования

1. Остановите службу "Сервер ККТ" (если она запущена)


2. Запустите TCP_test.exe на том компьютере, к которому подключен кассовый аппарат


3. В группе Сервер укажите порт 52111 и нажмите "Старт". Должна появиться надпись "Активен"Если "Активен" не появилось, а выдалось сообщение об ошибке, то, скорее всего, указанный порт уже используется другой программой. Попробуйте указать другой порт (от 2000 до 65535) и повторите попытку.


4. В группе Клиент укажите адрес 127.0.0.1, порт 52111 и нажмите "Старт". Также должна появиться надпись "Активен", а у сервера должно появиться сообщение "connect from: 127.0.0.1"Если "Активен" не появилось, попробуйте отключить брандмауэр, файрволы, антивирусы и т.д. (или добавить в них разрешение на TCP-порт 52111)


5. Далее запустите TCP_test.exe на втором компьютере (где не будет подключен кассовый аппарат, но будет запускаться 1С). В группе Клиент укажите ip-адрес первого компьютера, порт 52111 и нажмите "Старт". Также должна появиться надпись "Активен", а у сервера (на первом компьютере) должно появиться сообщение "connect from: х.х.х.х" (адрес второго компьютера)Если "Активен" не появилось, то нужно проверять настройки брандмауэра, файрвола, антивирусов на первом компьютере. В этих настройках нужно разрешить входящие TCP-соединения на порт 52111


6. Далее на обоих компьютерах нажмите Стоп в группе Сервер и в группе Клиент


7. KKT_Server_Setting.exe на том компьютере, к которому подключен кассовый аппарат. Включите запись файла лога и режим эмулятора. Нажмите кнопку "Сохранить настройки". Должен создаться файл kkt_server.ini с указанными настройкамиЕсли файл kkt_server.ini не создался, то нужно разбираться с правами пользователя на папку, откуда запускается KKT_Server_Setting.exe


8. Запустите службу "Сервер ККТ". Должен создаться файл лога

   22.08.2019 18:28:54	Emulation Start on port 52111
   Server version: 2.0.8.10   Server mode: Emulation version 2.5   ServerInterfaceRevision: 2005

   Если служба не запустилась, в файле лога будет указана причина ошибки. Если файл лога не создался, то нужно разбираться с правами службы на запись в ту папку, откуда она запускается.



9. В программе TCP_test.exe на первом и на втором компьютере нажмите Старт в группе Клиент. Должны появиться надписи "Активен", а в файле лога должны появиться строки:

   22.08.2019 18:35:37	Emulation ClientConnect 127.0.0.1
   22.08.2019 18:37:05	Emulation ClientConnect 192.168.1.48
   

   Если надпись "Активен" в TCP_test не появилась, тогда нужно искать причину, используя описание ошибки в TCP_test.
    
10. Если все эти действия выполнены успешно, то проблем с сетевыми подключениями не должно быть.